[Googleスプレッドシート] URL(Path)の末尾だけ抽出する
Office※ 本記事はアフィリエイト広告(Amazonアソシエイト)を含みます。
URLの一覧から、最後のファイル名やスラッグだけを取り出したい。SPLIT で分割して最後の列を拾う、みたいなことをするより、素直に正規表現でぶっこ抜く方が早いです。
基本形
=REGEXEXTRACT(A2,"[^/]+$")
| A2 | 結果 |
|---|---|
https://example.com/blog/hello-world | hello-world |
https://example.com/files/report.csv | report.csv |
[^/]+$ は「/ 以外の文字が1文字以上続いて、そのまま末尾で終わる部分」という意味。つまり最後の / より後ろです。
末尾が / で終わるURLに対応する
https://example.com/blog/hello-world/ のように最後が / で終わるURLだと、/ の後ろに何もないので基本形はエラー(#N/A)になります。末尾の / を許容するならこう。
=REGEXEXTRACT(A2,"([^/]+)/?$")
( ) で囲んだ部分だけが取り出されるので、末尾の / は結果に含まれません。
クエリ(?以降)やアンカー(#以降)を除く
?utm_source=... のようなパラメーター付きのURLも混ざっているなら、? と # も区切り文字として扱います。
=REGEXEXTRACT(A2,"([^/?#]+)/?(?:[?#].*)?$")
| A2 | 結果 |
|---|---|
https://example.com/blog/hello-world/ | hello-world |
https://example.com/page.html?utm_source=x | page.html |
https://example.com/docs/intro#setup | intro |
ここまで来ると読みにくいので、データがきれいなら基本形で十分です。
拡張子を外す
末尾に .csv とか .html とかついているのを外したいときは、追加で
=SUBSTITUTE(REGEXEXTRACT(A2,"[^/]+$"),".html","")
としてあげれば消せる。拡張子がバラバラなら、「最後の . 以降」を正規表現で消す方が楽です。
=REGEXREPLACE(REGEXEXTRACT(A2,"[^/]+$"),"\.[^.]+$","")
列まるごと処理する
1行ずつコピーせず、ARRAYFORMULA で列全体に一発でかけられます。
=ARRAYFORMULA(IF(A2:A="","",REGEXEXTRACT(A2:A,"([^/]+)/?$")))
IF(A2:A="","", ...) は空行でエラーを出さないためのおまじない。
まとめ
| やりたいこと | 式 |
|---|---|
| 最後の / 以降 | =REGEXEXTRACT(A2,"[^/]+$") |
| 末尾の / を許容 | =REGEXEXTRACT(A2,"([^/]+)/?$") |
| 拡張子を外す | =REGEXREPLACE(REGEXEXTRACT(A2,"[^/]+$"),"\.[^.]+$","") |
逆に、URLからドメインだけを取り出したいときはURLからドメインだけを抜き出すをどうぞ。
GoogleSpreadsheet